ACTIVE SERVER PAGE

아래 .Item(cdoSMTPServer) =  "xxx.xxx.xxx.xxx" 부분을 수정해주셔야하고,
메타태그 있어야 함 상수에 필요로 함



<!--METADATA TYPE="TypeLib" NAME="CDO for Windows 2000 Type Library"
UUID="{CD000000-8B95-11D1-82DB-00C04FB1625D}" -->
<%
Function SendMailRemoteSMTP(strSubject, strContent, strFrom, strTo, iFormat)
    Dim objMsg, objConf, objFields

    Set objMsg = CreateObject("CDO.Message")
    Set objConf = CreateObject("CDO.Configuration")
    Set objFields = objConf.Fields

    'IIS에 있는 기본 설정을 가지고 온다.
    objConf.Load 1

    Set objFields = objConf.Fields
   
    With objFields
        ' cdoSendUsingMethod = cdoSendUsingPickup 일때 Pickup 폴더를 지정해준다.
        '.Item(cdoSMTPServerPickupDirectory) = "c:\Inetpub\mailroot\Pickup"
       
        ' 메일 서버
        .Item(cdoSMTPServer) =  "xxx.xxx.xxx.xxx"
        ' 메일 서버의 포트 번호
        .Item(cdoSMTPServerPort) = 26

        ' 타임아웃
        ' Default is 30 seconds
        .Item(cdoSMTPConnectionTimeout) = 30

       '.Item(cdoLanguageCode) = ""

       ' 메일 전송 방법
       ' cdoSendUsingPickup - 로컬 SMTP의 Pickup 폴더를 이용
       ' cdoSendUsingPort - 원격 네트워크를 이용
       ' Default is cdoSendUsingPickup
       .Item(cdoSendUsingMethod) = cdoSendUsingPort

       ' 인증 방법
       ' cdoAnonymous - 익명 액세스
       ' cdoBasic - 기본 인증
       '  - Windows 보안 패키지
       ' Default is cdoAnonymous
       '.Item(cdoSMTPAuthenticate) = cdoAnonymous
       .Item(cdoSMTPAuthenticate) = cdoBasic
       ' 익명 액세스 인증이 아닐 경우
       .Item(cdoSendUserName) = "계정"
       .Item(cdoSendPassword) = "암호"
.Item(cdoURLGetLatestVersion) = True
      .Update
    End  With

    With objMsg
   
    Set .Configuration = objConf
        .Subject = strSubject
       
        If iFormat = 1 Then
            .TextBody = strContent
        Else
            .HTMLBody = strContent
        End If
       
        .From = strFrom
        .To = strTo
        '.ReplyTo = strReply
        '.AddAttachment "C:\files\another.doc"
        .Send
    End  With

Set objFields = Nothing
Set objConf = Nothing
Set objMsg = Nothing
End Function 

SendMailRemoteSMTP "테스트제목1","테스트내용1","cak0280@daum.net","cak0280@skylla.co.kr","1"
%>